Lights Out: Classic Edition 1.0.0 - Scenyx Entertainment Community

Rules

Lights Out: Classic Edition 1.0.0, completly redone

Options

flattspott

Sep 7 2004, 01:32 AM

Post #1

X-S Freak

Group: Moderator
Posts: 1787
Joined: 14-April 03
From: Southern California
Member No.: 32293
Xbox Version: v1.0
360 version: v1 (xenon)

I changed pretty much everything about it.
I wanted it to be pretty much resourceless (so BJ can hardcode it into MXM)

Just need to add in the sound handler stuff and it'll be good to go.

I spent the most part of today checking all 50 macros to see if they work, which they do.

Here it is. Please let me know what you think fellow WIPers...

Save as LightsOutCE.xsm and stick it you PlugIns folder

CODE

<XSM>
<Title>Lights Out: Classic Edition</Title>
<MinimumBuild>1231</MinimumBuild>
<Description>A puzzle game</Description>
<GUID>{F56C71F3-22A8-037A-6B4F-02D4EC15003A}</GUID>
<Class>Popup</Class>
<Category>Game</Category>
<Author>flattspott</Author>
<Version>1.0.0</Version>

<script>
Set Size 36
Set Padding 2.5
Set PointerColor 0x60000000
Set MacroSpeed 250
Set CurrentLevel 0
Set OnColor 0xFF0000CB
Set OffColor 0xFFFFFFFF
Set InfoColor Yellow
Set BackColor Black
Set IsMacro 0
Set AlignX 135
Set AlignY 150
Set RandomPalette 0 // 0 = Off - Set this to 1 to override the default colors with random ones (might make it look like crap though)

// ########### Experimental Random On/Off Colors #############
If# %RandomPalette% != 0 Then
For P = 0 To 1
For X = 0 To 3
SetFunc C%X% CvtToBase 16 0 %($rand%255)%
Next
Set CP%P% %C0%%C1%%C2%%C3%
Next
Set OnColor 0x%CP0%
Set OffColor 0x%CP1%
EndIf

Set Audible 0
Gosub SoundHandler
Gosub LoadLevel

:GameLoop
SetFunc Input IQPeekMsgID
If %Input% != "" Gosub InputHandler
If# %IsMacro% != 1 Gosub WinCheck
Gosub DrawLevel
Goto GameLoop

:InputHandler
IQWaitMsg Any
Switch %MSG_ID%
Case KEY_LF
Gosub PreviousLevel
If# %Audible% != 0 Then
Playsound Sound2
EndIf
EndCase
Case KEY_RT
Gosub NextLevel
EndCase
Case UI_UP
Gosub PointerU
EndCase
Case UI_DN
Gosub PointerD
EndCase
Case UI_LF
Gosub PointerL
EndCase
Case UI_RT
Gosub PointerR
EndCase
Case UI_SELECT
Gosub PointerC
EndCase
Case MUSIC_NEXT
Gosub MacroSolve
EndCase
Case SYS_MENU
XMLOpen Game %0%
XMLGetValue Game AuthorData !^Author
XMLGetValue Game VersionData !^Version
XMLGetValue Game TitleData !^Title
XMLClose Game
CallScript Documentation
EndCase
Case UI_VIRTKB
CallScript _GetColor "Off Color" %OffColor% "On Color" %OnColor%
Set OnColor %_Color2%
Set OffColor %_Color1%
EndCase
Case UI_BACK
If# %Audible% != 0 Then
For ToClose = 1 To 4
CloseSound Sound%ToClose%
Next
EndIf
Quit
EndCase
EndSwitch
Return

:PreviousLevel
If# %CurrentLevel% != 0 Then
Sub CurrentLevel 1
Gosub LoadLevel
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:NextLevel
If# %CurrentLevel% != %MaxLevels% Then
Add CurrentLevel 1
Gosub LoadLevel
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:SoundHandler
SetFunc DoesExists FileExists "C:\\Audio\\MainAudio\\Global A Button Select.wav"
If# %DoesExists% != 0 Then
LoadSound Sound1 "C:\\Audio\\MainAudio\\Global A Button Select.wav"
LoadSound Sound2 "C:\\Audio\\MainAudio\\Global Keyboard Stroke 1.wav"
LoadSound Sound3 "C:\\Audio\\MainAudio\\Global Scroll Beep.wav"
LoadSound Sound4 "C:\\Audio\\AmbientAudio\\AMB_EC_Steam3.wav"
Set Audible 1
EndIf
Return

:MacroSolve
If %MacroData% == "" Goto AbortMacro
Set IsMacro 1
Gosub LoadLevel
Gosub DrawLevel
SetFunc MacroLength Length %MacroData%
For I = 0 To %MacroLength%
SetFunc MacroPart Mid %I% 1 %MacroData%
If %MacroPart% != "" Then
Gosub Pointer%MacroPart%
EndIf
Gosub DrawLevel
DelayMS %MacroSpeed%
Next
Gosub LoadLevel
Gosub DrawLevel
Set IsMacro 0
:AbortMacro
Return

:PointerL
If# %Column% != 0 Then
Sub Column 1
Sub LightIndex 1
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:PointerR
If# %Column% != %MaxColumns% Then
Add Column 1
Add LightIndex 1
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:PointerD
If# %Row% != %MaxRows% Then
Add Row 1
Add LightIndex %GridSize%
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:PointerU
If# %Row% != 0 Then
Sub Row 1
Sub LightIndex %GridSize%
If# %Audible% != 0 Then
PlaySound Sound3
EndIf
EndIf
Return

:PointerC
Switch %LightIndex%
Case 0
For p = 0 To 2
Set P%p% %LightIndex%
Next
Add P1 1
Add P2 %GridSize%
Set ChangeCount 2
EndCase
Case 1
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 1
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 2
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 1
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 3
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 1
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 4
For p = 0 To 2
Set P%p% %LightIndex%
Next
Sub P1 1
Add P2 %GridSize%
Set ChangeCount 2
EndCase
Case 5
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 9
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 10
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 14
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 15
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Add P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 19
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 %GridSize%
Set ChangeCount 3
EndCase
Case 20
For p = 0 To 2
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Add P2 1
Set ChangeCount 2
EndCase
Case 21
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 1
Set ChangeCount 3
EndCase
Case 22
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 1
Set ChangeCount 3
EndCase
Case 23
For p = 0 To 3
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 1
Set ChangeCount 3
EndCase
Case 24
For p = 0 To 2
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Set ChangeCount 2
EndCase
Default
For p = 0 To 4
Set P%p% %LightIndex%
Next
Sub P1 %GridSize%
Sub P2 1
Add P3 1
Add P4 %GridSize%
Set ChangeCount 4
EndCase
EndSwitch
For A = 0 to %ChangeCount%
Set ThisLight %P{A}%
Set TempLight %Light{ThisLight}%
If# %TempLight% == 1 Then
Set Light%P{A}% 0
Else
Set Light%P{A}% 1
EndIf
Next
Add Moves 1
If# %Audible% != 0 Then
PlaySound Sound1
EndIf
Return

:LoadLevel
Set Row 0
Set Column 0
Set LightIndex 0
Set Moves 0
XMLOpen Game %0%
XMLGetValue Game InitialData !.Classic^Level:%CurrentLevel%~Initial
XMLGetValue Game MacroData !.Classic^Level:%CurrentLevel%~Macro
XMLGetValue Game MoveData !.Classic^Level:%CurrentLevel%~Minimum
XMLGetValue Game GridSize !.Classic~Gridsize
XMLGetValue Game MaxLevels !.Classic~Number
Set MaxRows %(GridSize-1)%
Set MaxColumns %(GridSize-1)%
For I = 0 To %(GridSize*GridSize)%
SetFunc Light%I% Mid %I% 1 %InitialData%
Next
XMLClose Game
Return

:DrawLevel
BeginDraw
Box 0 0 640 480 %OnColor% %OnColor%
Box 100 100 440 280 %BackColor% %BackColor%
Set CurrentLight 0
For Y = 0 To %MaxRows%
For X = 0 To %MaxColumns%
If# %Light{CurrentLight}% == 1 Then
Box %(X*Size+AlignX+Padding)% %(Y*Size+AlignY+Padding)% %(Size-Padding)% %(Size-Padding)% %OnColor% %OnColor%
Else
Box %(X*Size+AlignX+Padding)% %(Y*Size+AlignY+Padding)% %(Size-Padding)% %(Size-Padding)% %OffColor% %OffColor%
EndIf
Add CurrentLight 1
Next
Next
Set PointerX %(Column*Size+AlignX)%
Set PointerY %(Row*Size+AlignY)%
Box %(PointerX+Padding)% %(PointerY+Padding)% %(Size-Padding)% %(Size-Padding)% %PointerColor% %PointerColor%
If# %IsMacro% == 1 Then
Text 360 230 Left "Macro Enabled" %OffColor%
Else
Text 345 200 Left "Current Level: %CurrentLevel%$eol$Minimum Moves: %MoveData%$eol$Total Moves: %Moves%" %OffColor%
EndIf
EndDraw
Return

:WinCheck
If# %IsMacro% == "1" Goto AbortWinCheck
Set Counter 0
For ToCheck = 0 To %(GridSize*GridSize-1)%
If# %Light{ToCheck}% == 0 Then
Add Counter 1
EndIf
Next
If# %Counter% == %(GridSize*GridSize)% Then
BeginDraw
Box 0 0 640 480 %OnColor% %OnColor%
Box 100 100 440 280 %BackColor% %BackColor%
Text 320 180 Center "Congradulations$eol$You've completed level %CurrentLevel%$eol$$eol$Press any key to advance to level %(CurrentLevel+1)%" %InfoColor%
EndDraw
IQClear
IQWaitMsg Any
If# %CurrentLevel% == %MaxLevels% Then
Set CurrentLevel 1
Else
Add CurrentLevel 1
EndIf
Gosub LoadLevel
Goto GameLoop
EndIf
:AbortWinCheck
Return
</Script>
<SubScripts>
<script Name="Documentation">
Set Info "Credits:$EOL$$EOL$%TitleData%$EOL$Version - %VersionData%$eol$Author - %AuthorData%$EOL$$EOL$Description:$EOL$$EOL$This electronic puzzle by Tiger Toys consists$EOL$of a 5 x 5 grid of buttons which also have$EOL$lights in them. By pressing a button, its light$EOL$and those of the (non-diagonally) adjacent$EOL$buttons will change (switch on if it was off,$EOL$and vice versa). Given a pattern of lights,$EOL$you have to switch them all off by pressing$EOL$the correct buttons. Not only that, but you$EOL$have to do it in as few moves as possible.$EOL$$EOL$Controls:$EOL$$EOL$[D-Pad] moves the pointer$EOL$[A] toggles the light order$EOL$[X] plays a macro solution$EOL$[Y] to view documentation$EOL$[B] to quit or go back$EOL$[R and L Triggers + D-Pad] changes levels"
Set Top 380
Set Counter 0

:Loop
SetFunc Input IQPeekMsgID
If %Input% != "" Gosub InputHandler
Gosub Draw
If# %Audible% != 0 Then
Playsound Sound4
EndIf
Sub Top 1
Add Counter 1
If# %Counter% >= 900 Then
Quit
EndIf
Goto Loop

:InputHandler
IQWaitMsg Any
If %MSG_ID% == "UI_SELECT" Then
IQClear
IQWaitMsg Any
EndIf
If %MSG_ID% == "UI_BACK" Then
Quit
EndIf
Return

:Draw
BeginDraw

For Effect = 0 To 10
Set TempSize %($rand%20)%
Box %(Effect*($rand%100))% %(Effect*($rand%100))% %TempSize% %TempSize% %OnColor% %OnColor%
Box %(Effect*($rand%100))% %(Effect*($rand%100))% %TempSize% %TempSize% %OffColor% %OffColor%
Next

Text 320 %Top% Center "%Info%" White
Box 0 0 100 480 %OnColor% %OnColor%
Box 540 0 100 480 %OnColor% %OnColor%
Box 0 0 640 100 %OnColor% %OnColor%
Box 0 380 640 100 %OnColor% %OnColor%
EndDraw
Return
</Script>
</SubScripts>
<Classic Number="49" Gridsize="5">
<Level Initial="0000000000101010000000000" Macro="DDDCRRCRRCDCLLCLLC" Minimum="6" />
<Level Initial="1010110101000001010110101" Macro="DCRRCRRCDLLLLDCRRCRRC" Minimum="6" />
<Level Initial="0101011011110111101101010" Macro="RRCDCDLLCRRRRCDLLCDC" Minimum="6" />
<Level Initial="0000011011000001000111011" Macro="CRCRRCRCDDDDCLLLLC" Minimum="6" />
<Level Initial="1111011101111010001111011" Macro="RCDRRCDLLLCRRRCDDRCLLLLC" Minimum="6" />
<Level Initial="0000000000101011010101110" Macro="RRCDLCRCRCDLLLCRRRRCDDLLC" Minimum="7" />
<Level Initial="1111010001100011000111110" Macro="RRCDLLCDRCRCRRCDLLLLCDRRC" Minimum="7" />
<Level Initial="0000000100010101010101010" Macro="DDRRDCDLLCRCRCRCRCUULLC" Minimum="7" />
<Level Initial="0101011111011100101111100" Macro="DRCRRCDLCDLCRRCDLCLLC" Minimum="7" />
<Level Initial="0111001110011100000000000" Macro="CRCRRCRCDLLLCRCRC" Minimum="7" />
<Level Initial="1010110101101011010101110" Macro="CRRRRCDLCLCLCDLCRRRRCDDLLC" Minimum="8" />
<Level Initial="1111101010110110111001010" Macro="CRRRRCDLLCDLLCRRCRRCDLLLCRRC" Minimum="8" />
<Level Initial="0001000101010101010001000" Macro="RRRCDLCRRCDLLLCRRCDLLLCRRCDLC" Minimum="8" />
<Level Initial="0000000000010000100001000" Macro="RRRRCDLCRCDLLCRRCDLLCRCDLC" Minimum="8" />
<Level Initial="0000001000000000100000000" Macro="RRRCDLCRCRCDDCLCLCDRC" Minimum="8" />
<Level Initial="1000010000100001000011111" Macro="RCDCRCDLCRRCDCLCRRCDLLLLC" Minimum="9" />
<Level Initial="0000000000001000111011111" Macro="RRCDLCRCRCDRCLLLLCDRRRRCDLLCLLUC" Minimum="8" />
<Level Initial="0010001010101010101000100" Macro="RRCDLCRRCDRCLLCLLCDRCRRCDLC" Minimum="9" />
<Level Initial="1010100000101010000010101" Macro="DCRRCRRCDCLLCLLCDCRRCRRC" Minimum="9" />
<Level Initial="0000000000100010000000000" Macro="RRRCRCDLLCDCLCRRRCDLLCDRCRC" Minimum="9" />
<Level Initial="0111101000011100100001000" Macro="CRRRCDLLLCDRRRCDRCLLLCLCDRCRCRRC" Minimum="10" />
<Level Initial="0111010001100011000101110" Macro="RCRRRCDCLLLLCDRRRCRCDLLCDCLCLC" Minimum="10" />
<Level Initial="0000000000001110011000100" Macro="RRRCRCDLLCDCLCRRRCDLCLLLCDCRRC" Minimum="10" />
<Level Initial="0000000000100011111101001" Macro="CRRCDCRCLLLCDRRCRRCDLCLLCDRRRC" Minimum="10" />
<Level Initial="1000011000111001111001111" Macro="CRRCRCDRCDCLLCLCDCRCDRRC" Minimum="10" />
<Level Initial="1000110001111111000110001" Macro="RRRCRCDCLLCLLCDRRCRCRCDDLCLCLLC" Minimum="11" />
<Level Initial="0010001110001000010000100" Macro="CRCRCDCLCRRCDCLCRRCDDCLC" Minimum="11" />
<Level Initial="0000000000001110011100111" Macro="RRRCRCDLLCDCLCRRRCDLCLLLCDCRRCRRC" Minimum="11" />
<Level Initial="0000001000000000000000000" Macro="RRCDCLCRRCDRCLLLCLCDRCRRRCDLCLC" Minimum="11" />
<Level Initial="0000000000001000000000000" Macro="RRRCRCDLLCDCLCRRRCDCLLLLCDCRRCRC" Minimum="11" />
<Level Initial="1000111001101011001110001" Macro="RCRCDRCRCDCLLLLCDRCRCRRCDCLCLLLC" Minimum="12" />
<Level Initial="1111100010001000100011111" Macro="CRRCDLCRRRCDCLLLCDLCRRRCDCLCLCLC" Minimum="12" />
<Level Initial="0001000010101011000110011" Macro="RRCDCLCDLCRRCDCLCRRCRCDCLCLLLC" Minimum="12" />
<Level Initial="0010110001100010110101111" Macro="RRCDLCRRCRCDCLLCLCDCRRCRCDLLLCLC" Minimum="12" />
<Level Initial="0001101010100011010100000" Macro="CRCRCRRCDLCLLCDCRCDLCRRRCDLCLC" Minimum="12" />
<Level Initial="0010001010100011111110001" Macro="RCRRRCDCLCLLCLCDRRRCRCDLCLCLCDCRRRC" Minimum="13" />
<Level Initial="0000001110011100111000000" Macro="RCRRCDCRCLLLCLCDRRCDLCLCRRRCRCDLCLLC" Minimum="13" />
<Level Initial="1010101010101010101010101" Macro="CRRRRCDLCLCLCDCRCRCDCLCLCDLCRRRRC" Minimum="13" />
<Level Initial="0101010000110000011001010" Macro="RCRCRRCDCLCLLCLCDCRCRCRRCDLCLLC" Minimum="13" />
<Level Initial="0000000000010100000000000" Macro="RRCRCRCDLCLLCDCLCRRCDLCRRCDCLCRRC" Minimum="13" />
<Level Initial="1000101010001000010000100" Macro="RCRRRCDLCLCLCDLCRRCRCDCRCLLLCLCDCRRRC" Minimum="14" />
<Level Initial="1110010010111001001011100" Macro="CRRCDLCRRCDRCLLCLCLCDCRCRCRCRCDC" Minimum="14" />
<Level Initial="1000111010111000100001110" Macro="RCRRRCDLCLCLCDRCRCDRCLCLLCLCDRCRCRC" Minimum="14" />
<Level Initial="0000011011111110010001110" Macro="CRRRCDCRCLLCLCLCDRRCRCRCDLCLLCDCLC" Minimum="14" />
<Level Initial="0111010100001111111010101" Macro="CRRCRCDRCLCLCLCLCDRCRCDRCLLCDCRRRC" Minimum="14" />
<Level Initial="0010001110111110111000100" Macro="RCRRRCDCLCLLCLCDRRCRCRCDLCLCLCDCLCRRC" Minimum="15" />
<Level Initial="0010011111101000100100001" Macro="RCRRRCDCLCLLCLCDCRRCRCDCLCLCLCDCRRRC" Minimum="15" />
<Level Initial="0000010001001001000100000" Macro="RCRRRCDCLCLCLCLCDCRRCRCDCLLCDCLCRRC" Minimum="15" />
<Level Initial="1000101010001000101010001" Macro="RCRRRCDLCLCLCDLCRRCRCDCRCLLLCLCDCRCRC" Minimum="15" />
<Level Initial="1111111111111111111111111" Macro="RRRCRCDCLCLLCLCDCRCRCDCLCRRCDCLCLLC" Minimum="15" />
</Classic>
</XSM>

This post has been edited by flattspott: Sep 7 2004, 06:38 AM

Taiger	Sep 7 2004, 08:44 PM Post #2
X-S Young Member Group: Members Posts: 42 Joined: 13-June 03 Member No.: 43656 Xbox Version: v1.2	I would if I had a WIP release

geniusalz	Sep 9 2004, 05:10 AM Post #3
Team MXM Group: Head Moderator Posts: 1827 Joined: 3-January 03 Member No.: 16298 Xbox Version: v1.1 360 version: unknown	I would, if my xbox wasn't packed in my suitcase

BenJeremy	Sep 9 2004, 11:33 AM Post #4
X-S Elysian Group: Head Moderator Posts: 9688 Joined: 19-July 02 Member No.: 1853 Xbox Version: v1.1 360 version: v1 (xenon)	I would, if I wasn't in Toronto on business

tandylyons

Sep 9 2004, 12:34 PM

Post #5

X-S Senior Member

Group: Members
Posts: 254
Joined: 8-January 03
From: Brisbane, Australia
Member No.: 17690
Xbox Version: v1.1

QUOTE

I would if I had a WIP release

QUOTE

I would, if my xbox wasn't packed in my suitcase

QUOTE

I would, if I wasn't in Toronto on business

As for me. I would.... Nah I'm just too damn lazy.

*sigh*

And I don't have a WIP release.

flattspott	Sep 9 2004, 03:13 PM Post #6
X-S Freak Group: Moderator Posts: 1787 Joined: 14-April 03 From: Southern California Member No.: 32293 Xbox Version: v1.0 360 version: v1 (xenon)	Everyones so busy as of late.

chilin_dude	Sep 9 2004, 03:51 PM Post #7
X-S Knowledgebase Group: Members Posts: 4945 Joined: 12-January 03 From: USA Member No.: 19165 Xbox Version: v1.0 360 version: unknown	I would if I hadn't just started my I.T.C A level course

BenJeremy	Sep 10 2004, 05:27 AM Post #8
X-S Elysian Group: Head Moderator Posts: 9688 Joined: 19-July 02 Member No.: 1853 Xbox Version: v1.1 360 version: v1 (xenon)	I'll try it as soon as I get back (Sunday, maybe). Just wrapping up coding on the network startup/shutdown event handling code, so the FTP server can survive a change in network settings. Just have to add the command in ActionScripting to refresh the network settings from the XML (which basically should shut down any current FTP connections, de-init the network and then reconfigure and initialize with the new settings)

SumDumGuy3	Sep 10 2004, 05:14 PM Post #9
X-S Young Member Group: Members Posts: 53 Joined: 10-August 04 Member No.: 137432	I would if I weren't tied up writing and testing scripts for v "n"... I would if I were a "fellow WIPer"... I would if my "MXM_VDog.xas" had not eaten my code... hahah, sorry had to jump in on that one... was too funny...

SumDumGuy3	Oct 1 2004, 06:58 AM Post #10
X-S Young Member Group: Members Posts: 53 Joined: 10-August 04 Member No.: 137432	Wow, very nice... and very compact for such a kickin little game. It probably would have taken me 3 or 4 times as many lines of code... nice work... Well, I am off to try some of your other scripts and code snippets... Keep'em comin SDG

flattspott	Oct 1 2004, 01:09 PM Post #11
X-S Freak Group: Moderator Posts: 1787 Joined: 14-April 03 From: Southern California Member No.: 32293 Xbox Version: v1.0 360 version: v1 (xenon)	LOL Check my first lights out thread. This lightweight version is after a lot of tuning.

« Next Oldest · MXM WIP Beta forum · Next Newest »

Display Mode: Standard · Switch to: Linear+ · Switch to: Outline

Track this topic · Email this topic · Print this topic · Subscribe to this forum

Lo-Fi Version

Time is now: 24th May 2013 - 09:53 PM

Licensed to: Scenyx